Как автоматически посчитать число страниц в разных файлах?

3 декабря, 2020

Всем привет!

Есть техническая проблема, прошу помощи в автоматизации.

Ситуация: мне принесли жесткий диск с разрозненными файлами. Там могут быть договоры и прочие документы в формате doc, docx, xls, xlsx и подобные (пока сам не знаю точно какие, еще не видел диск). Некоторые документы могут быть по одной странице, некоторые по 1000 страниц. Допустим, на диске будет 5123 документа (наугад написал, скорее всего будет больше).

Мне нужно узнать объём выполняемой работы в страницах. Каждый понимает, что оплатить труд по анализу 50 страниц дешевле, чем по анализу 5000 страниц. Кроме того, чем больше страниц, тем больше время требуется на работу.

Стандартный вариант: открыть вордом или экселем документ, нажать кнопку "печать" и в предпросмотре увидеть количество страниц в данном документе при выводе на печать. И сделать это 5123 раза подряд, суммируя результаты. Это труд, который может занять море времени.

Как посчитать автоматически количество страниц во всех документах при выводе их на печать, не открывая каждый из них отдельно?

3 декабря, 2020

Поиск подсказал один из способов
Как посчитать количество страниц сразу в нескольких документах Word

сам не проверял, нет образцов файлов Word

3 декабря, 2020

19 минут назад, kmscom сказал:

один из способов
Как посчитать количество страниц сразу в нескольких документах Word

Так всё равно надо будет сидеть и потом на калькуляторе плюсовать страницы, так что под условия задачи не подходит.

19 минут назад, kmscom сказал:

Поиск подсказал один из способов

В поиске можно найти это https://www.sql.ru/forum/953973/kak-poschitat-obshhee-kolichestvo-stranic-teksta-v-nabore-faylov-word-a

Вроде как раз то что нужно, но там делалось для старого ворда. Так что если для .doс и будет работать (не проверял), то для docx и так ясно, что работать не будет. Ибо это уже по структуре это документ внутри архива. На всякий случай код .vbs скрипта из последнего вложения там

With CreateObject("word.application")
  For Each x In CreateObject("scripting.filesystemobject").getfile(wscript.scriptfullname).parentfolder.Files
    If LCase(Mid(x.Name, InStrRev(x.Name, ".") + 1, 3)) = "doc" Then
      With .documents.open(x.Path, , True) 'ReadOnly
        numDocs = numDocs + 1
        sumPages = sumPages + .Content.ComputeStatistics(2) 'wdStatisticPages
'        sumPages = sumPages + .BuiltInDocumentProperties(14) 'wdPropertyPages 'считает неправильно!
        .Close False 'don't save changes
      End With
    End If
  Next
  .Quit
End With
wscript.echo "Всего страниц " & sumPages & Chr(13) & "Документов " & numDocs

Изменено 3 декабря, 2020 пользователем regist

3 декабря, 2020

1 час назад, regist сказал:

Так всё равно надо будет сидеть и потом на калькуляторе плюсовать страницы, так что под условия задачи не подходит.

Зачем? Там ведь отобразиться количество страниц сразу нескольких документов.

3 декабря, 2020

3 часа назад, kmscom сказал:

Поиск подсказал один из способов

Там есть один момент: "Замечание: Если в списке присутствуют файлы, в которых нет подсчёта страниц, то в столбце Число страниц (Pages) указано ничего не будет."

2 часа назад, regist сказал:

Так всё равно надо будет сидеть и потом на калькуляторе плюсовать страницы, так что под условия задачи не подходит.

3 часа назад, kmscom сказал:

Их хотя бы не надо открывать каждый, уже хорошо.

3 декабря, 2020

Не вижу, где там показывает сразу у нескольких документов.

Попробовал способ через колонку "Число страниц" на MS Office 2019, Windows 10 x64,

система корректно показывает кол-во страниц только у документов, созданных этим же Office 2019 (как doc, так и docx),

у других doc, например, созданных в Office 2003, показывает всегда число 1.

А еще часто бывают rtf, там вообще не отображается.

Попробовал способ через vbs, считает долго (т.к. открывает в скрытом виде каждый документ), но посчитало правильно.

Для docx тебе ничего исправлять в скрипте не надо, т.к. во первых проверяются только первые 3 буквы после последней точки в имени файла,

во-вторых, документ открывается точно также как и doc, не смотря на другую его структуру, ведь скрипт берёт значение от самого Word-а,

не анализируя внутренности файла самостоятельно.

Сделал обобщённый вариант vbs, с подсчетом раздельно и в сумме DOC*, XLS*, RTF со сканом рекурсивно (с подкаталогами):

Dim numXDocs, sumXSheets, sumXPages, numWDocs, sumWPages

set oExcel = CreateObject("excel.application")
set oWord = CreateObject("word.application")
set root = CreateObject("scripting.filesystemobject").getfile(wscript.scriptfullname).parentfolder
Analysis(root)

oExcel.Quit: oWord.Quit
set oExcel = Nothing: set oWord = Nothing: set root = Nothing

wscript.echo _
	"DOC*, RTF:" & Chr(13) & _
	"Всего страниц: " & sumWPages & Chr(13) & "Документов: " & numWDocs & _
	Chr(13) & Chr(13) & "XLS*" & Chr(13) & _
	"Всего страниц: " & sumXPages & Chr(13) & "Всего листов: " & sumXSheets & Chr(13) & "Документов: " & numXDocs & _
	Chr(13) & Chr(13) & "-----------------" & Chr(13) & "Общее:" & Chr(13) & Chr(13) & _
	"Страниц: " & sumXPages + sumWPages & Chr(13) & "Документов: " & numXDocs + numWDocs
	
Sub Analysis(root)

	With oExcel
	  For Each x In root.Files
		If LCase(Mid(x.Name, InStrRev(x.Name, ".") + 1, 3)) = "xls" Then
		  With .workbooks.open(x.Path, , True) 'ReadOnly
			numXDocs = numXDocs + 1
			sumXSheets = sumXSheets + .sheets.count
			For Each sheet in .sheets
			  sumXPages = sumXPages + (sheet.HPageBreaks.Count + 1) * (sheet.VPageBreaks.Count + 1)
			Next
			.Close False 'don't save changes
		  End With
		End If
	  Next
	  .Quit
	End With
	
	With oWord
	  For Each x In root.Files
	    ext = LCase(Mid(x.Name, InStrRev(x.Name, ".") + 1, 3))
		if ext = "doc" or ext = "rtf" then
          With .documents.open(x.Path, , True) 'ReadOnly
            numWDocs = numWDocs + 1
            sumWPages = sumWPages + .Content.ComputeStatistics(2) 'wdStatisticPages
            .Close False 'don't save changes
          End With
		end if
	  Next
    End With

	For Each x in root.SubFolders: Analysis(x): Next

End Sub

Изменено 3 декабря, 2020 пользователем Dragokas

3 декабря, 2020

1 час назад, Dragokas сказал:

Сделал обобщённый вариант vbs, с подсчетом раздельно и в сумме DOC*, XLS*, RTF со сканом рекурсивно (с подкаталогами):

Спасибо! А как его запускать? В блокнот скопировать и сменить расширение на *.vbs?

3 декабря, 2020

6 часов назад, Воронцов сказал:

Зачем? Там ведь отобразиться количество страниц сразу нескольких документов.

Нескольких, но число то выводится для каждого отдельно, а не суммарное в папке.

2 часа назад, Mrak сказал:

В блокнот скопировать и сменить расширение на *.vbs?

да.

4 декабря, 2020

В блокноте - Сохранить как - тип файла "Все файлы" и сменить расширение на .vbs

Закинуть в нужную папку и запустить.

3 ноября, 2022

03.12.2020 в 19:59, Dragokas сказал:
Не вижу, где там показывает сразу у нескольких документов.

Попробовал способ через колонку "Число страниц" на MS Office 2019, Windows 10 x64,

система корректно показывает кол-во страниц только у документов, созданных этим же Office 2019 (как doc, так и docx),

у других doc, например, созданных в Office 2003, показывает всегда число 1.

А еще часто бывают rtf, там вообще не отображается.

Попробовал способ через vbs, считает долго (т.к. открывает в скрытом виде каждый документ), но посчитало правильно.

Для docx тебе ничего исправлять в скрипте не надо, т.к. во первых проверяются только первые 3 буквы после последней точки в имени файла,

во-вторых, документ открывается точно также как и doc, не смотря на другую его структуру, ведь скрипт берёт значение от самого Word-а,

не анализируя внутренности файла самостоятельно.

Сделал обобщённый вариант vbs, с подсчетом раздельно и в сумме DOC*, XLS*, RTF со сканом рекурсивно (с подкаталогами):
Dim numXDocs, sumXSheets, sumXPages, numWDocs, sumWPages

set oExcel = CreateObject("excel.application")
set oWord = CreateObject("word.application")
set root = CreateObject("scripting.filesystemobject").getfile(wscript.scriptfullname).parentfolder
Analysis(root)

oExcel.Quit: oWord.Quit
set oExcel = Nothing: set oWord = Nothing: set root = Nothing

wscript.echo _
	"DOC*, RTF:" & Chr(13) & _
	"Всего страниц: " & sumWPages & Chr(13) & "Документов: " & numWDocs & _
	Chr(13) & Chr(13) & "XLS*" & Chr(13) & _
	"Всего страниц: " & sumXPages & Chr(13) & "Всего листов: " & sumXSheets & Chr(13) & "Документов: " & numXDocs & _
	Chr(13) & Chr(13) & "-----------------" & Chr(13) & "Общее:" & Chr(13) & Chr(13) & _
	"Страниц: " & sumXPages + sumWPages & Chr(13) & "Документов: " & numXDocs + numWDocs
	
Sub Analysis(root)

	With oExcel
	  For Each x In root.Files
		If LCase(Mid(x.Name, InStrRev(x.Name, ".") + 1, 3)) = "xls" Then
		  With .workbooks.open(x.Path, , True) 'ReadOnly
			numXDocs = numXDocs + 1
			sumXSheets = sumXSheets + .sheets.count
			For Each sheet in .sheets
			  sumXPages = sumXPages + (sheet.HPageBreaks.Count + 1) * (sheet.VPageBreaks.Count + 1)
			Next
			.Close False 'don't save changes
		  End With
		End If
	  Next
	  .Quit
	End With
	
	With oWord
	  For Each x In root.Files
	    ext = LCase(Mid(x.Name, InStrRev(x.Name, ".") + 1, 3))
		if ext = "doc" or ext = "rtf" then
          With .documents.open(x.Path, , True) 'ReadOnly
            numWDocs = numWDocs + 1
            sumWPages = sumWPages + .Content.ComputeStatistics(2) 'wdStatisticPages
            .Close False 'don't save changes
          End With
		end if
	  Next
    End With

	For Each x in root.SubFolders: Analysis(x): Next

End Sub

Drakokas, спасибо тебе большущее! Твой скрипт меня очень выручил. Случайно наткнулся на этот форум, когда гуглил способ подсчёта страниц огромного пакета документов. В моём случае вышло 113238 страниц. Как бы я считал это вручную - хз.

Как автоматически посчитать число страниц в разных файлах?

Рекомендуемые сообщения

Mrak

kmscom

regist

Воронцов

Mrak

Dragokas

Mrak

regist

Dragokas

Sentinel_Vash

Пожалуйста, войдите, чтобы комментировать

Похожий контент

Обзор

Активность

Магазин

Поддержка

Kaspersky Support Forum